**Avanço Real x Planejado no MS Project**

[[](https://www.linkedin.com/in/renato-luciano-de-ara%C3%BAjo-menezes-mba-29367818/)](https://www.linkedin.com/in/renato-luciano-de-ara%C3%BAjo-menezes-mba-29367818/)

**[Renato Luciano de Araújo Menezes, MBA](https://www.linkedin.com/in/renato-luciano-de-ara%C3%BAjo-menezes-mba-29367818/)**

Planejamento e Controle | PL-100 | PL-900 | Power Apps | Power Automate | Citizen Developer |MS Project | Power BI | Power Platform | VBA | Green Belt | Gerenciamento de Projetos | Oracle Primavera P6 |

[5 artigos](https://www.linkedin.com/in/renato-luciano-de-ara%C3%BAjo-menezes-mba-29367818/recent-activity/posts/)

1 de fevereiro de 2022

Seguindo o tópico que comecei a abordar no post anterior, que falava sobre os indicadores gráficos no MS Project, hoje falarei sobre os indicadores personalizados para Avanço Previsto e Avanço Real.

Uma dos grandes desafios que assolam os planejadores que trabalham com o MS Project é a ausência de um campo que calcule o avanço planejado nos cronogramas.

Muitos tendem a pensar que essa é uma deficiência do software, entretanto, o que acontece é que existem inúmeras formas de realizar os cálculos, que podem ser feitos por ponderação de prazo, custo, trabalho, etc.

No meu caso, como trabalho com cronogramas de projetos de engenharia cujos produtos são documentos no formato A1 equivalente, dessa forma, foi necessário criar uma metodologia de cálculo própria levando em consideração as premissas particulares para este tipo de atividade.

Em suma, as premissas são:

1 - É feita uma ponderação baseada no custo dos marcos de projeto e o avanço é calculado de acordo com o A1 equivalente dos documentos previstos (pretendo fazer um post exclusivo para este assunto);

2 - Atividades relacionadas a recebimento de comentários e informações a serem utilizadas nos projetos não tem peso.

Esta forma de ponderação foi escolhida pois o avanço físico real do projeto só ocorre quando há emissão de documentos, portanto, para o efetivo controle do avanço é melhor que apenas as atividades que gerem produtos físicos possuam peso.

Uma vez que os pesos são distribuídos e a linha de base do projeto é definida, as seguintes fórmulas aplicadas a um campo personalizado do tipo texto são utilizadas.

AVANÇO PLANEJADO

A fórmula utilizada para o cálculo do avanço planejado está descrita a seguir.

***IIf([Término da linha de base]=ProjDateValue("ND");"S/ LINHA DE BASE";IIf(round(IIf([Custo da linha de base]=0;IIf([Data de status]<[Término da linha de base];0;100);IIf([Data de status]<[Início da Linha de Base];0;([COTA]/[Custo da linha de base]\*100))))>100;100;round(IIf([Custo da linha de base]=0;IIf([Data de status]<[Término da linha de base];0;100);IIf([Data de status]<[Início da Linha de Base];0;([COTA]/[Custo da linha de base]\*100)))))) & "%"***

*Basicamente* é utilizada a função IIf, que é semelhante ao SE do Excel e possui a seguinte estrutura:

IIf(CONDIÇÃO A SER TESTADA; RESULTADO SE A CONDIÇÃO FOR VERDADEIRA; RESULTADO SE A CONDIÇÃO FOR FALSA).

A fórmula utiliza várias funções IIf aninhadas, o que significa que se a condição não for verdadeira serão feitos outros testes até chegarmos a algum resultado.

 Dessa forma, o funcionamento da fórmula se dá da seguinte forma:

**1 -      *IIf([Término da linha de base]=ProjDateValue("ND");"S/ LINHA DE BASE";***

No primeiro passo, a fórmula verifica se o projeto possui linha de base, uma vez os cálculos só podem ser feitos caso ela esteja definida.

Se não houver linha de base definida, o campo informará “S/ LINHA DE BASE”.

Caso exista linha de base, será feito o teste seguinte.

**2 -      *IIf(round(IIf([Custo da linha de base]=0;***

O teste seguinte verifica se a atividade tem peso por meio do custo da linha de base, caso esse custo seja zero significa que a atividade não possui peso (pode ser uma atividade relacionada a comentários do cliente ou medição por exemplo).

Se a atividade não tiver custo da linha de base associado, será feito outro teste, que é se a tarefa já deveria ter sido finalizada ou não.

**2.1 -   *IIf([Data de status]<[Término da linha de base];0;100);***

A verificação é feita comparando-se a data de status com o término da linha de base.

Se a tarefa já deveria ter sido finalizada, o valor do avanço planejado será de 100%.

Se a tarefa ainda está no prazo, o valor do avanço planejado será de 0%

OBS: Seria possível nesse caso adicionarmos uma ponderação pelo prazo da tarefa como acontecia no cronograma antigo mas atualizar avanços intermediários em atividades sem peso seria um trabalho extra para a equipe. Se eventualmente atribuirmos peso a estas atividades elas serão calculadas de outra forma e este teste deixará de acontecer automaticamente.

**2.2 -   *IIf([Data de status]<[Início da Linha de Base];0;([COTA]/[Custo da linha de base]\*100))))>100;100;***

 2.2 – Caso a tarefa tenha custo da linha de base associado, ela verificará as seguintes condições:

Se a data de status é menor do que o início da linha de base, o avanço planejado será de 0% uma vez que a tarefa ainda não deveria ter sido iniciada.

Se a data de status é maior ou igual ao início da linha de base significa que a tarefa já deveria ter sido iniciada e portanto existe um avanço planejado, que é dado pela COTA que indica o quanto do custo da linha de base já deveria ter sido gasto até o momento da data de status dividido pelo custo da linha de base daquela tarefa como um todo multiplicado por 100 para obtermos a %.

No nosso caso, o campo COTA fica igual ao custo da linha de base no momento em que a data de status fica maior ou igual ao término da linha de base por causa do acumulado no fim que definimos para o recurso ponderador.

Uma possível melhoria passível de implementação é distribuirmos o recurso ponderador na planilha de uso da tarefa no MS Project de acordo com as datas de emissão dos documentos dentro de um mesmo marco.

Se por quaisquer motivos o cálculo obter um valor maior que 100%, o valor será 100% de toda forma.

**3 -      *round(IIf([Custo da linha de base]=0;IIf([Data de status]<[Término da linha de base];0;100);***

***IIf([Data de status]<[Início da Linha de Base];0;([COTA]/[Custo da linha de base]\*100)))))) & "%"***

 A última parte da fórmula refaz os mesmos passos anteriores mas retorna o valor do % planejado caso ele seja menor ou igual a 100% e a função *round* serve apenas para arredondar o valor.

AVANÇO REAL

 Para o cálculo do avanço real, a seguinte fórmula é utilizada:

***IIf([Término da linha de base]=ProjDateValue("ND");"S/ LINHA DE BASE";(IIf([% concluída]=0;0 & "%";IIf([% concluída]=100;100 & "%";IIf([Custo da linha de base]=0;[% concluída] & "%";round([Custo real]/[Custo da linha de base]\*100) & "%")))))***

São seguidas as seguintes etapas de cálculo.

**1 -    *IIf([Término da linha de base]=ProjDateValue("ND");"S/ LINHA DE BASE";***

A primeira parte da fórmula faz a verificação se a linha de base não existe, caso realmente não exista temos o resultado “S/ LINHA DE BASE”

**2 -    *(IIf([% concluída]=0;0 & "%";***

Caso a % concluída da tarefa seja 0% o avanço real também será 0% em qualquer situação.

**3 -    *IIf([% concluída]=100;100 & "%";***

Caso a % concluída da tarefa seja 100% o avanço real também será 100% em qualquer situação.

**4 -    *IIf([Custo da linha de base]=0;[% concluída] & "%";***

Na última parte da fórmula, será verificado se a tarefa possui peso (custo da linha de base), se não houver peso, o avanço real será igual à % concluída.

**4.1 - *round([Custo real]/[Custo da linha de base]\*100) & "%")))))***

Caso exista peso (custo da linha de base) na tarefa, o avanço real será dado pela relação entre o custo real até a data de status, que é derivado da % concluída, e o custo total da linha de base.

O valor resultante é multiplicado por 100 e arredondado para que obtenhamos o valor final do avanço real.

 Ressalto que a fórmula de cálculo aqui adota é válida somente para processos análogos ao da emissão de documentos de engenharia em que, ou foram emitidos (100%) ou não foram (0%).

Existem diversas outras formas de cálculo de avanço planejado x real que podem ser seguidas de acordo com a necessidade do projeto.

<https://www.linkedin.com/pulse/avan%C3%A7o-real-x-planejado-ms-project-de-ara%C3%BAjo-menezes-mba/?originalSubdomain=pt>